; -----------------------------------------------------------
; firstBoot: demo of firstBoot behavior. Program will show different
; behavior depending on whether it runs as an autoexec or is
; double-clicked from the deskTop.
; -----------------------------------------------------------
.if	Pass1
	.include geosSym
	.include geosMac
.endif
; -----------------------------------------------------------
	lda	#2	;50% stipple
	jsr	SetPattern
	LoadB	r2L,0
	LoadB	r2H,199
	LoadW	r3,0
	LoadW	r4,319
	jsr	Rectangle	;clear screen
	lda	firstBoot
	beq	10$
	LoadW	a0,clicked
	bra	20$
10$	LoadW	a0,autoexec
20$	ldy	#0
30$	lda	(a0),y
	sta	text3b,y
	beq	40$
	iny
	bne	30$
40$	LoadW	r0,infoDlg
	jsr	DoDlgBox
	jmp	EnterDeskTop
; -----------------------------------------------------------
; info dialog
; -----------------------------------------------------------
infoDlg:	.byte	SET_DB_POS | 1
	.byte	28,156
	.word	64,255
	.byte	DBTXTSTR,64,14
	.word	title
	.byte	DBTXTSTR,12,29
	.word	text1a
	.byte	DBTXTSTR,12,41
	.word	text1b
	.byte	DBTXTSTR,12,56
	.word	text2a
	.byte	DBTXTSTR,12,68
	.word	text2b
	.byte	DBTXTSTR,12,83
	.word	text3a
	.byte	DBTXTSTR,12,95
	.word	text3b
	.byte	OK,9,105
	.byte	0	;end of dialog box definition
; -----------------------------------------------------------
title:	.byte	BOLDON,"- firstBoot -",PLAINTEXT,0
text1a:	.byte	"This program demonstrates the",0
text1b:	.byte	"firstBoot system variable in GEOS.",0
text2a:	.byte	"It is clear during boot, but set to $ff",0
text2b:	.byte	"after the deskTop has been loaded.",0
text3a:	.byte	"Its current status is: ",0
text3b:	.block	30
; -----------------------------------------------------------
autoexec:	.byte	BOLDON,"LOADED VIA AUTOEXEC",PLAINTEXT,0
clicked:	.byte	BOLDON,"LOADED VIA DOUBLE-CLICK",PLAINTEXT,0